qtwayland-5.15.18.ebuild 1.3 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455
  1. # Copyright 1999-2026 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  3. EAPI=8
  4. # Looking for Qt 6? It is packaged differently to Qt 5 with different
  5. # package names: https://wiki.gentoo.org/wiki/Project:Qt/Qt6_migration_notes
  6. if [[ ${PV} != *9999* ]]; then
  7. QT5_KDEPATCHSET_REV=1
  8. KEYWORDS="amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv x86"
  9. fi
  10. inherit qt5-build
  11. DESCRIPTION="Wayland platform plugin for Qt"
  12. SLOT=5/${QT5_PV} # bug 815646
  13. IUSE="compositor vulkan"
  14. RDEPEND="
  15. dev-libs/wayland
  16. =dev-qt/qtcore-${QT5_PV}*:5=
  17. =dev-qt/qtgui-${QT5_PV}*:5=[egl,libinput,vulkan=]
  18. media-libs/libglvnd
  19. x11-libs/libxkbcommon
  20. compositor? ( =dev-qt/qtdeclarative-${QT5_PV}*:5= )
  21. "
  22. DEPEND="${RDEPEND}
  23. vulkan? ( dev-util/vulkan-headers )
  24. "
  25. BDEPEND="dev-util/wayland-scanner"
  26. src_configure() {
  27. local myqmakeargs=(
  28. --
  29. -no-feature-xcomposite-egl
  30. -no-feature-xcomposite-glx
  31. $(qt_use compositor feature-wayland-server)
  32. $(qt_use compositor feature-wayland-dmabuf-server-buffer)
  33. $(qt_use compositor feature-wayland-drm-egl-server-buffer)
  34. $(qt_use compositor feature-wayland-shm-emulation-server-buffer)
  35. )
  36. use compositor && myqmakeargs+=(
  37. $(qt_use vulkan feature-wayland-vulkan-server-buffer)
  38. )
  39. qt5-build_src_configure
  40. }
  41. src_install() {
  42. qt5-build_src_install
  43. rm "${D}${QT5_BINDIR}"/qtwaylandscanner || die
  44. }