qtdeclarative-5.15.18-r1.ebuild 1.6 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869
  1. # Copyright 2009-2025 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  3. EAPI=8
  4. if [[ ${PV} != *9999* ]]; then
  5. QT5_KDEPATCHSET_REV=1
  6. KEYWORDS="amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv x86"
  7. fi
  8. PYTHON_COMPAT=( python3_{11..14} )
  9. inherit flag-o-matic python-any-r1 qt5-build
  10. DESCRIPTION="The QML and Quick modules for the Qt5 framework"
  11. IUSE="cpu_flags_x86_sse2 gles2-only +jit localstorage vulkan +widgets"
  12. REQUIRED_USE="jit? ( x86? ( cpu_flags_x86_sse2 ) )"
  13. # qtgui[gles2-only=] is needed because of bug 504322
  14. DEPEND="
  15. =dev-qt/qtcore-${QT5_PV}*
  16. =dev-qt/qtgui-${QT5_PV}*:5=[gles2-only=,vulkan=]
  17. =dev-qt/qtnetwork-${QT5_PV}*
  18. =dev-qt/qttest-${QT5_PV}*
  19. media-libs/libglvnd
  20. localstorage? ( =dev-qt/qtsql-${QT5_PV}* )
  21. widgets? ( =dev-qt/qtwidgets-${QT5_PV}*[gles2-only=] )
  22. "
  23. RDEPEND="${DEPEND}"
  24. BDEPEND="${PYTHON_DEPS}"
  25. PATCHES=(
  26. "${FILESDIR}/${PN}-5.14.2-QQuickItemView-fix-maxXY-extent.patch" # QTBUG-83890
  27. "${FILESDIR}/${P}-CVE-2025-12385.patch" # bug 966269, QTBUG-141515
  28. )
  29. src_prepare() {
  30. qt_use_disable_mod localstorage sql \
  31. src/imports/imports.pro
  32. qt_use_disable_mod widgets widgets \
  33. src/src.pro \
  34. src/qmltest/qmltest.pro \
  35. tests/auto/auto.pro \
  36. tools/tools.pro \
  37. tools/qmlscene/qmlscene.pro \
  38. tools/qml/qml.pro
  39. qt5-build_src_prepare
  40. }
  41. src_configure() {
  42. replace-flags "-Os" "-O2" # bug 840861
  43. local myqmakeargs=(
  44. --
  45. -qml-debug
  46. $(qt_use jit feature-qml-jit)
  47. )
  48. qt5-build_src_configure
  49. }
  50. src_install() {
  51. qt5-build_src_install
  52. qt5_symlink_binary_to_path qml 5
  53. qt5_symlink_binary_to_path qmleasing 5
  54. qt5_symlink_binary_to_path qmlpreview 5
  55. qt5_symlink_binary_to_path qmlscene 5
  56. }